Source of digraphs.plp

<(common.inc.plp)><:

my $mode = $Request || 'vim';
my $include = 'digraphs' . ($mode ne 'vim' && "-$mode");
my $cmp = exists $get{cmp} ? ($get{cmp} // 1) : !!$Request;

my $di = eval { Data($include) } || {};
warn "error in $include: ", @{$@} if ref $@;

Html({
	title => "$mode digraph cheat sheet",
	version => '1.4',
	description => $di->{description} // [
		"Complete table of digraph characters from",
		($di->{title} // $mode) . ".",
	],
	keywords => [@{ $di->{keywords} // [] }, qw'
		digraph mnemonic compose composition pair
		character char glyph table unicode vim
	'],
	stylesheet => [qw'light'],
	data => ["data/$include.json"],
});

%{$di} or Abort(
	"Requested digraphs <q>$mode</q> not available",
	'404 request not found',
);

say "<h1>$di->{title} Digraphs</h1>";
say "<p>$_</p>" for $di->{intro} // ();

if (exists $get{v}) {
	# show characters for inverted mnemonics (vim alternatives)
	$di->{key}->{ substr($_, 1, 1) . substr($_, 0, 1) } ||= [
		$di->{key}->{$_}->[0], '', 'l0 ex', '', $di->{key}->{$_}->[4]
	] for grep { ref $di->{key}->{$_} } keys %{ $di->{key} };
}

my @chars = (
	[qw{! " % ' ( ) * + , - . /}],
	['0'..'9'], [qw{: ; < = > ?}],
	['A'..'M'], ['N'..'Z'],
	['a'..'m'], ['n'..'z'],
);
my @chars2 = (['_'], @chars);  # trailing character (extended set)
my @columns = !exists $get{split} ? \@chars2 :
	([@chars2[0, 1, 3, 4, 6]], [@chars2[2, 5, 7]]);

if ($mode eq 'xorg') {
	#TODO determine character usage from declared keys
	$chars2[0] = [qw( # ^ _ ` ~ )];
	@chars = @chars2;
}

for my $colchars (@columns) {
print '<table class="glyphs dimap"><col>';
print qq'<colgroup span="$_">' for map {scalar @$_} @{$colchars};
say '</colgroup><col>';
for my $section (qw{thead tfoot}) {
	print "<$section><tr><th>↳";
	print '<th>', EscapeHTML($_) for map {@$_} @{$colchars};
	say '<th>&nbsp;';
}
for my $c1group (@chars) {
	print '<tbody>';
	for my $c1 (@$c1group) {
		print '<tr><th>', EscapeHTML($c1);
		for my $c2 (map {@$_} @$colchars) {
			my $mnem = $c1 . $c2;
			if (not defined $di->{key}->{$mnem}) {
				print '<td>';
				next;
			}
			if (ref $di->{key}->{$mnem} ne 'ARRAY') {
				printf '<td class="X Xr" title="%s">', EscapeHTML($mnem);
				next;
			}
			my ($codepoint, $name, $support, $script, $string) =
				@{ $di->{key}->{$mnem} };

			my $glyph = $string || !!$codepoint && chr $codepoint;
			utf8::upgrade($glyph);  # prevent latin1 output
			my $desc = $mnem . ($name && " ($name)");
			my @class = ('X', grep {$_} $script);
			push @class, $cmp ? $support :
				$di->{flagclass}->{$support} // "u-$support" if $support;

			$glyph = EscapeHTML($glyph);
			$glyph = "<span>$glyph</span>" if $script =~ /\bZs\b/;

			printf "\n".'<td class="%s" title="%s">%s',
				join(' ', @class), EscapeHTML($desc), $glyph;
		}
		say "\n<th>", EscapeHTML($c1);
	}
}
say '</table>';
print '<hr>' if exists $get{split};
}

:>
<div class="legend"><: unless ($cmp) { :>
	<table class="glyphs"><tr>
	<td class="X Cc">control
	<td class="X Zs"><span>space</span>
	<td class="X Mn">combining
	<td class="X Sk">spacing&nbsp;modifier
	<td class="X Pf">quote
	<td class="X Po">punctuation
	<td class="X So">symbol
	<td class="X Sm">math
	<td class="X Sc">currency
	<td class="X No">numeric
	<td class="X Greek">greek
	<td class="X Cyrillic">cyrillic
	<td class="X Latin">latin
	<td class="X Hebrew">hebrew
	<td class="X Arabic">arabic
	<td class="X Hangul">korean
	<td class="X Hiragana">japanese
	<td class="X Bopomofo">chinese
	</table>
<: } :>
	<table class="glyphs"><tr><:
	printf qq(\n\t<td class="X %s">%s), $cmp ? $_ : $di->{flagclass}{$_} // "u-$_", $di->{flag}->{$_}
		for sort keys %{ $di->{flag} };
:>
	</table>
</div>

sheet.shiar.nl/source.plp version 1.4 created by Shiar • AGPLv3