Source of charset.plp

<(common.inc.plp)><:

Html({
	title => 'charset cheat sheet',
	version => '1.0',
	description => [
		"Reference sheet with all glyphs in common character encoding tables,",
		"and an overview of Unicode ranges and UTF-8 bytes.",
	],
	keywords => [qw'
		charset codepage unicode ascii utf8 latin glyph character encoding
		reference common overview table
	'],
	stylesheet => [qw'light'],
	data => [qw'charset-unicode.inc.pl charset-utf8.inc.pl'],
});

:>
<h1>Character encoding</h1>

<:
use Shiar_Sheet::FormatChar;
my $glyphs = Shiar_Sheet::FormatChar->new;
my @nibble = (0..9, 'A'..'F');
my $nibsize = 1;

use Encode qw(decode resolve_alias);
# generate character table(s)
# (~16x faster than decoding in loop;
#  substr strings is twice as fast as splitting to an array)
my %ALIAS = (
#	default => [qw(unicode utf-8 iso-8859-1 cp437 -cp1252- --iso-8859-15- -koi8-f)],
	default => [qw(unicode- utf-8 iso-8859-1 -cp1252- --iso-8859-15- cp437 -cp850)],
	0 => [qw(cp437 cp863)],
	1 => [qw(iso-8859-1 cp1252 MacRoman cp850)],
	2 => [qw(iso-8859-2 cp1250 cp852 MacCentralEurRoman MacCroatian MacRumanian)],
	5 => [qw(koi8-f iso-8859-5 cp1251 MacCyrillic cp855 cp866)],
	7 => [qw(iso-8859-7 cp1253 MacGreek cp737 cp869)],
	8 => [qw(iso-8859-8 cp1255 MacHebrew cp862)],
);
my @request = map {
	if (my $input = $_) {
		my %row = (offset => 0);
		my $endpoint = 255;
		if ($input =~ s/^--//) {
			$row{offset} = $endpoint > 160 ? 160 : 48;
		}
		elsif ($input =~ s/^-//) {
			$row{offset} = $endpoint > 128 ? 128 : 32;
		}
		if ($input =~ s/-$//) {
			$endpoint = $row{offset} ? $row{offset} < 160 ? 159 : 191 : 127;
		}

		if ($input =~ /^U([0-9a-f]+)(?:-([0-9a-f]+))?/) {
			my $start = hex($1) << ($2 ? 4 : 8);
			my $end = $2 ? hex($2) << 4 : $start + 240;
			$row{table} = join '', map { chr } $start .. $end+15;
			utf8::upgrade($row{table});  # prevent latin1 output
			$row{set} = sprintf 'Unicode block U+%02Xxx', $start >> 8;
		}
		elsif ($input eq 'U') {
			$row{table} = ' ' x 1024;
			$row{set} = 'Unicode planes';
			$row{cell} = do 'charset-ucplanes.inc.pl';
			@nibble = (map { $_.0, $_.8 } 0 .. 7);
			$nibsize = 8;
		}
		elsif ($row{set} = resolve_alias($input)) {
			if ($row{set} eq 'Internal') {
				$row{table} = ' ' x ($endpoint < 255 ? 640 : 8192);
				$row{set} = 'Unicode BMP';
				$row{cell} = do 'charset-unicode.inc.pl';
			}
			elsif ($row{set} eq 'utf-8-strict') {
				$row{table} = undef;
				$row{set} = 'UTF-8';
				$row{cell} = do 'charset-utf8.inc.pl';
			}
			else {
				$row{table} = decode($row{set}, pack 'C*', $row{offset} .. $endpoint);
			}
		}
		else {
			print "<p>Encoding $input unknown</p>\n";
		}
		\%row;
	}
	else {
		();
	}
} map { defined $ALIAS{$_} ? @{ $ALIAS{$_} } : $_ }
	$ENV{PATH_INFO} =~ /\w/ ? split(m{[/+\s]}, $ENV{PATH_INFO}) : 'default';
my $NOCHAR = chr 0xFFFD;

for my $cp437 (grep {$request[$_]->{set} eq 'cp437'} 0 .. $#request) {
	substr($request[$cp437]->{table}, 237, 1) = pack 'U*', 0x3D5; # phi sign
	substr($request[$cp437]->{table}, 0, 32) = pack 'U*', map {hex} qw(
		2007 263A 263B 2665 2666 2663 2660 2022 25D8 25CB 25D9 2642 2640 266A 266B 263C
		25BA 25C4 2195 203C 00B6 00A7 25AC 21A8 2191 2193 2192 2190 221F 2194 25B2 25BC
	);
}

for my $row (@request) {
	printf '<div class="section"><table class="glyphs%s">', !$row->{cell} && ' charmap';
	printf '<caption>%s</caption>', $row->{set};
	print '<col>' x 17;
	for my $section (qw{thead}) {
		print "<$section><tr><th>↱";
		print '<th>', $_ for @nibble;
		print "\n";
	}
	print '<tbody>';
	for my $msb (0 .. (length($row->{table}) || 256) - 1 >> 4) {
		printf '<tr><th>%X', $msb + ($row->{offset} >> 4);
		for my $lsb (0 .. $#nibble) {
			my $val = ( ($msb<<4) + $lsb ) * $nibsize;
			if ($row->{cell}) {
				print $row->{cell}->($val);
				next;
			}

			my $glyph = substr $row->{table}, $val, 1;
			if ($glyph eq $NOCHAR) {
				print '<td>';
				next;
			}

			print "\n".$glyphs->glyph_cell($glyph);
		}
		print "\n";
	}
	print "</table></div>\n";
}

:>
<hr>

<div class="legend">
	<table class="glyphs"><tr>
	<td class="X Cc">control
	<td class="X Zs"><span>whitespace</span>
	<td class="X Mn">diacritic<table class="glyphs"><tr>
		<td class="X Sk">letter
		</table>
	<td class="X Po">punctuation<table class="glyphs"><tr>
		<td class="X Pf">quote
		</table>
	<td class="X So">symbol<table class="glyphs"><tr>
		<td class="X Sm">math
		<td class="X Sc">currency
		</table>
	<td class="X No">numeric
	<td class="X Greek">greek<table class="glyphs"><tr>
		<td class="X Latin">latin
		<td class="X Cyrillic">cyrillic
		</table>
	<td class="X Aramaic">aramaic<table class="glyphs"><tr>
		<td class="X Brahmic">brahmic
		<td class="X Arabic">arabic
		</table>
	<td class="X Syllabic">syllabic<table class="glyphs"><tr>
		<td class="X African">african
		<td class="X Hiragana">japanese
		<td class="X Han">cjk
		<td class="X Bopomofo">chinese
		</table>
	<td class="X Alpha">alphabetic
	</table>

	<table class="glyphs"><tr>
	<td class="X">unicode 7.0
	<td class="X Xr">proposed
	<td class="X Xd">deprecated
	<td class="">unassigned
	<td class="X Xi">invalid
	</table>
</div>