Source of source.plp

<(common.inc.plp)><:

my $source = $ENV{PATH_INFO};
$source =~ s{^/}{};

if ($source =~ s{(?<=\Q.inc.pl\E)/jsonp?$}{} and -r $source) {
	# convert perl include to json construct
	checkmodified($source);
	eval {
		my $data = do $source or die $@ || $! || 'read error';
		require JSON;
		my $converter = JSON->new;
		$converter->utf8->indent->space_after->canonical;

		$header{content_type} = 'application/json';
		$header{content_type} = 'text/plain' if exists $get{debug};
		print $_, '(' for $get{callback} // ();
		print $converter->encode($data);
		print     ')' for $get{callback} // ();
		return 1;
	} or do {
		$header{status} = '500 File unavailable';
		$header{content_type} = 'text/plain';
		print "Conversion failed: $@";
	};
	exit;
}

Html({
	title => "$source source code",
	version => 'v1.1',
	description => !$source ? 'Index of source files for this site.' : [
		"Source code of the $source file at this site,",
		"with syntax highlighted and references linked."
	],
	keywords => [qw'
		sheet cheat source code perl plp html agpl
	'],
	stylesheet => [qw'light dark mono red'],
});

print "\n";

if (not $source) {
	print "<h1>Source files</h1>";

	print "<p>Project code distributed under the AGPL. Please contribute back.</p>";
	print '<ul>'."\n";
	for (glob '*.plp') {
		chomp;
		printf '<li><a href="/source/%s">%1$s</a></li>'."\n", EscapeHTML($_);
	}
	print "</ul>\n\n";
}
else {
	print "<h1>Source of $source</h1>\n";

	if ($source =~ m{(?:/|^)\.}) {
		die "File request not permitted\n";
	}
	elsif ($source =~ s{::}{/}g or !-e $source) {
		$source .= '.pm';
		for (0 .. $#INC) {
			-e ($_ = "$INC[$_]/$source") or next;
			$source = $_;
			last;
		}
	}
	-r $source or die "Requested file not found\n";

	if (eval { require Text::VimColor and Text::VimColor->VERSION(0.12) }) {
		delete $Text::VimColor::SYNTAX_TYPE{Underlined};
		my %TYPETAG = (
			Statement => 'strong',
			Error     => 'em',
			Todo      => 'em',
		);

		my $hl = Text::VimColor->new(
			file => $source,
			vim_options => [@Text::VimColor::VIM_OPTIONS, '+:set enc=utf-8'],
		);
		my $parsed = $hl->marked;
		print "<pre>\n";
		foreach (@$parsed) {
			my $tag = $_->[0] && ($TYPETAG{ $_->[0] } || 'span');
			my $arg = '';
			print "<$tag$arg class=\"sy-\l$_->[0]\">" if $tag;
			if (!$_->[0] || $_->[0] eq 'Constant'
			and $_->[1] =~ s{^(['"]?)(/?[a-z0-9_.]+\.(?:plp?|css|js))(?=\1$)}{}) {
				printf '%s<a href="%s">%s</a>', $1, "/source/$2", $2;
			}
			if (!$_->[0] and $_->[1] =~ s/^(\s*)([A-Z]\w+(?:::\w+)+)(?![^;\s])//) {
				printf '%s<a href="%s">%s</a>', $1, "/source/$2", $2;
			}
			print Text::VimColor::_xml_escape($_->[1]);
			print "</$tag>" if $tag;
		}
		print "</pre>\n";
	}
	else {
		require Encode;
		print "<pre>\n";
		print EscapeHTML(Encode::decode_utf8(ReadFile($source)));
		print "</pre>\n";
	}

	print "\n";
}