Source of font.plp

<(common.inc.plp)><:

my $font = $Request;

Html({
	title => 'font coverage '.($font ? "for $font" : 'sheet'),
	version => '1.4',
	keywords => [qw(
		unicode font glyph char character support overview cover coverage
		script block symbol sign mark reference table
	)],
	stylesheet => [qw( light dark mono circus red )],
	data => [qw( data/unicode-cover.inc.pl )],
});

if ($font) {
	my $fontmeta = eval { Data("data/font/$font") }
		or Abort("Unknown font $font", '404 font not found', ref $@ && $@->[1]);

	my $map = eval {
		$get{map} or return;

		my $groupinfo = Data('data/unicode-cover');

		my ($cat, $name) = split m{/}, $get{map}, 2 or die "invalid map\n";
		if (!$name) {
			($cat, $name) = ('table', $cat);
		}

		my $row = $groupinfo->{$cat}->{$name}
			or die "unknown character group $cat/$name\n";
		my $query = $row->{query};

		my @map;
		for (map { split /[^\d-]/ } $query) {
			my @range = split /-/, $_, 2;
			m/^[0-9]+$/ or die "Invalid code point $_ in query $query\n" for @range;
			push @map, $_ for $range[0] .. ($range[1] // $range[0]);
		}
		return \@map;
	};
	Abort($@, '404 invalid query') if $@;

	require Unicode::UCD;

	my $pagerows = 0x200;
	my $pagecols = 32;
	my $offset = eval {
		local $_ = $get{q} || 0;
		return $_ if /\A\d+\z/;  # numeric
		return hex $1 if /\A (?: 0?x | u\W* ) ([0-9a-f]+) \z/ix;  # hexadecimal
		return $_->[0]->[0] for Unicode::UCD::charblock(ucfirst) || ();  # block
		die "Unknown offset query '$_'\n";
	};
	Abort($@, '400 invalid offset') if $@;

	say "<h1>Font coverage</h1>";
	say "<h2>$_</h2>" for EscapeHTML($fontmeta->{name});
	printf("<p>Version <strong%s>%s</strong> released %s contains %d glyphs.",
		!!$_->[2] && qq( title="revision $_->[2]"),
		$_->[1], $_->[0],
		scalar @{ $fontmeta->{cover} },
	) for [
		grep { $_ }
		($fontmeta->{date} || '?') =~ s/T.*//r,
		EscapeHTML($fontmeta->{version}),
		$fontmeta->{revision},
	];
	for ($fontmeta->{os}) {
		say '<br>';
		print ucfirst join(' ',
			"distributed",
			(map { "by $_" } $fontmeta->{oscorp} || "various sources"),
			(map { "with <em>$_</em>" } $_ || ()),
			('and published as freeware "Core Web font"') x ($_ eq 'Windows 2000'),
			(map { "under a $_ license" }
				map { $fontmeta->{license} ? qq(<a href="$fontmeta->{license}" rel=nofollow>$_</a>) : $_ }
				$_ && $_ ne 'Android' ? 'proprietary' : 'free',
			),
		);
		print '.';
	}
	say '</p>';
	say "<p>$_</p>" for EscapeHTML($fontmeta->{copyright}) || ();

	require Shiar_Sheet::FormatChar;
	my $glyphs = Shiar_Sheet::FormatChar->new;

	my %cover = map { ($_ => 1) } @{ $fontmeta->{cover} };  # lookup map

	say <<"EOT";

<style>
	.glyphs tbody th[!colspan] { text-align: right }
	.glyphs tbody td { font-family: "$fontmeta->{name}" }
	.glyphs tbody td:nth-child(18) { border-left-width: 2px }
	\@font-face {
		font-family: "$fontmeta->{name}";
		src: url(/data/font/$font.ttf);
	}
</style>
EOT
	say '<table class="glyphs big">';

	my $offsetlink = '?' . join('&amp;',
		(map { $_ . '=' . EncodeURI($get{$_}) } grep { defined $get{$_} } qw{ map }),
		'q',
	);
	say "<caption>$_</caption>" for join(' ', grep {$_}
		$offset > $pagerows && sprintf('<a rel="start" href="%s=%d">◄</a>', $offsetlink, 0),
		$offset > 0 && sprintf(
			'<a rel="prev nofollow" href="%s=%d" title="U+%2$04X">◅</a>',
			$offsetlink, $offset - $pagerows,
		),
		sprintf('U+%04X', $map ? $map->[$offset] : $offset),
		Unicode::UCD::charblock($map ? $map->[$offset] : $offset),
		$offset + $pagerows < ($map ? @{$map} : 0x11_0000) && sprintf(
			'<a rel="next nofollow" href="%s=%d" title="U+%2$04X">▻</a>',
			$offsetlink, $offset + $pagerows,
		),
	);

	for my $cp ($offset .. $offset+$pagerows-1) {
		$cp = $map->[$cp] or next if $map;

		state $colpos;
		my $block = Unicode::UCD::charblock($cp);
		if ($block ne (state $sameblock = $block) and $block ne 'No_Block') {
			print '<tbody>';
			printf '<tr><th colspan=%d>%s', $pagecols+1, $block
				unless $block eq 'No_Block';
			say '';
			$sameblock = $block;
			$colpos = 0;
		}

		if ($map) {
			# compare previous code point and indicate gaps
			state $lastcp = 0;
			if ($cp != ++$lastcp) {
				if (!$colpos or $colpos++ % $pagecols > $pagecols - 3) {
					# nearly last column, start new row
					$colpos = 0;
				}
				else {
					# mark repositioning in existing row
					printf '<th>%X', $cp;
				}
				$lastcp = $cp;
			}
		}

		say sprintf '<tr><th>%X', $cp if $colpos++ % $pagecols == 0;

		my $info = $glyphs->glyph_info($cp);
		my ($class, $name, $mnem, $entity, $string) = @{$info};
		my $np = $class =~ /\bC\S\b/;  # noprint if control or invalid
		# display literal character, with placeholder circle if non-spacing/enclosing
		$string ||= ($class =~ /\bM[ne]\b/ && chr 9676) . chr($cp);
		my $html = $np ? !!$cover{$cp} && sprintf("&#%d;", $cp) :
			EscapeHTML($string);
		say sprintf '<td class="%s" title="U+%04X%s">%s',
			!$class ? ('l0', $cp, '', '') : (
			$cover{$cp} ? $np ? 'l2' : 'l5' : $np ? 'Xi' : 'l1',
			$cp, !!$name && ": $name",
			$html
			);
	}
	say '</table>';

	exit;
}

:>
<h1>Font coverage</h1>

<p>
Character support of Unicode
<a href="/charset">blocks</a> and <a href="/unicode">presets</a>.
</p>

<div>

<:

my $cover = Data('data/unicode-cover');

my @ossel = @{ $cover->{osdefault} };
my @fontlist = map { @{ $cover->{os}->{$_} } } @ossel;

my @rows = (
	'version/11',
	'version/63',
	'block/Latin-1 Supplement',
	'block/Latin Extended-A',
	'block/Latin Extended Additional',
	'block/Latin Extended-B',
	'script/Latin',
	'script/Greek',
	'script/Cyrillic',
	'script/Arabic',
	'script/Hebrew',
	'script/Devanagari',
	'script/Thai',
	'script/Hangul',
	'table/japanese',
	'script/Han',
	'table/ipa',
	'table/punctuation',
	'block/Dingbats',
	'table/symbols',
	'category/Sc', # currency
	'table/math',
	'category/Sm', # mathematical
	'table/arrows/single',
	'table/lines/single',
	'table/block',
	'table/lines',
	'table/html',
);

if (my $group = $get{q}) {
	my $grouprows = $cover->{$group}
		or Abort("Unknown character category $_", 404);
	@rows = map { "$group/$_" } sort keys %{$grouprows};
}

# output character list

print '<table class="mapped cover">';
print '<col><col>';
print "<colgroup span=$_>"
	for map { scalar @{ $cover->{os}->{$_} } } @ossel;

print '<thead><tr>';
print '<th colspan=2>';
for my $os (@ossel) {
	my $osfonts = $cover->{os}->{$os};
	my $osfont = $cover->{fonts}->[ $osfonts->[0] ]; # first font
	printf '<td colspan=%d>%s', scalar @{$osfonts}, $osfont->{os} || ''
}

print '<tr>';
print '<th colspan=2>';
printf('<td title="%s"><a href="%s">%s</a>', map { EscapeHTML($_) }
	join("\n", $_->{name}, $_->{description}),
	"/font/$_->{file}",
	$_->{abbr},
) for @{ $cover->{fonts} }[@fontlist];
say '</thead>';

for (@rows) {
	my ($group, $name) = split m{/}, $_, 2;
	my $row = $cover->{$group}->{$name};

	print '<tr>';
	$name = sprintf 'Unicode v%.1f', $name / 10 if $group eq 'version';
	$name = sprintf '<a href="%s">%s</a>', EncodeURI("/chars/$group/$name"), EscapeHTML($name)
		if $row->{count} and $row->{count} < 1280;
	print '<th>', $name;
	print '<td class=right>', $row->{count};
	for my $count (@{ $row->{support} }[@fontlist]) {
		if (not defined $count) {
			print '<td class="l0">?';
			next;
		}
		if (not $count) {
			print '<td class="l1">✘';
			next;
		}
		if ($count == $row->{count}) {
			print '<td class="l5">✔';
			next;
		}

		my $rel = $count / $row->{count};
		my $class = $rel < .5 ? 2 : $rel < .9 ? 3 : 4;
		printf '<td class="%s">%d', "l$class", $rel*10;
	}
	say '</tr>';
}

say "</table>\n";

:></div>

sheet.shiar.nl/source.plp version 1.4 created by Shiar • AGPLv3